Linux 命令总结之 awk

awk简介
使用方法
awk 的原理
awk 内置变量
awk 运算符
awk 正则
常用字符串函数
- 字符串函数的应用

awk简介

awk其名称得自于它的创始人 Alfred Aho 、Peter Weinberger 和 Brian Kernighan 姓氏的首个字母。实际上 AWK 的确拥有自己的语言： AWK 程序设计语言，三位创建者已将它正式定义为“样式扫描和处理语言”。它允许您创建简短的程序，这些程序读取输入文件、为数据排序、处理数据、对输入执行计算以及生成报表，还有无数其他的功能。

awk 是一种很棒的语言，它适合文本处理和报表生成，其语法较为常见，借鉴了某些语言的一些精华，如 C 语言等。在 linux 系统日常处理工作中，发挥很重要的作用，掌握了 awk将会使你的工作变的高大上。 awk 是三剑客的老大，利剑出鞘，必会不同凡响。

使用方法

awk '{pattern + action}' {filenames}

尽管操作可能会很复杂，但语法总是这样，其中 pattern 表示 AWK 在数据中查找的内容，而 action 是在找到匹配内容时所执行的一系列命令。花括号（{}）不需要在程序中始终出现，但它们用于根据特定的模式对一系列指令进行分组。 pattern就是要表示的正则表达式，用斜杠括起来。

awk语言的最基本功能是在文件或者字符串中基于指定规则浏览和抽取信息，awk抽取信息后，才能进行其他文本操作。完整的awk脚本通常用来格式化文本文件中的信息。

通常，awk是以文件的一行为处理单位的。awk每接收文件的一行，然后执行相应的命令，来处理文本。

awk 的原理

通过一个简短的命令，我们来了解其工作原理。

[root@Gin scripts]# awk '{print $0}' /etc/passwd
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin
.....................................................
 
[root@Gin scripts]# echo hhh|awk '{print "hello,world"}'
hello,world
 
[root@Gin scripts]# awk '{print "hiya"}' /etc/passwd
hiya
hiya
hiya
hiya
.....................................................

你将会见到/etc/passwd 文件的内容出现在眼前。现在，解释 awk 做了些什么。调用 awk时，我们指定/etc/passwd 作为输入文件。执行 awk 时，它依次对/etc/passwd 中的每一行执行 print 命令。

所有输出都发送到 stdout，所得到的结果与执行 cat /etc/passwd 完全相同。现在，解释{ print }代码块。在 awk 中，花括号用于将几块代码组合到一起，这一点类似于 C 语言。在代码块中只有一条 print 命令。在 awk 中，如果只出现 print 命令，那么将打印当前行的全部内容。

awk 内置变量

变量名	介绍
$0	当前记录
$1-$n	当前记录的第n个字段
FS	字段分隔符，默认为空格
RS	输入记录分隔符默认为换行符
NF	当前记录中的字段数，就是有多少列
NR	已经读出的记录数，就是行号，从1开始
OFS	输出字段分隔符，默认是空格
ORS	输出的记录分隔符，默认为换行符

实例

FS 字段分隔符

FS="\t+" 一个活多个tab分隔

  $ cat tab.txt 
  alk     al      a               k
  al      aaa             k               kasdj
  dl      j  
	
  $ awk 'BEGIN{FS="\t+"}{print $1,$2,$3,$4}' tab.txt 
  alk al a k
  al aaa k kasdj
  dl j jj lll

FS="[[:space:]+]" 一个或多个空白空格，默认的

  $ cat space.txt 
  we are    studing awk now!
	
  $ awk 'BEGIN{FS="[[:space:]+]"}{print $1,$2,$3,$4,$5,$6}' space.txt
  we are    studing

FS="[" ":]+" 以一个或多个空格或：分隔

  $ cat hello.txt
  root:x:0:0:root:/root:/bin/bash
  $ awk -F [" ":]+ '{print $1,$2,$3}' hello.txt
  root x 0

RS 记录分隔符

将FS设置成\n告诉awk每个字段都占据一行，通过将 RS 设置成”“，还会告诉 awk每个地址记录都由空白行分隔。

$ cat recode.txt
Jimmy the Weasel
100 Pleasant Drive
San Francisco,CA 123456
 
Big Tony
200 Incognito Ave.
Suburbia,WA 64890

$ cat awk.txt
#!/bin/awk
BEGIN {
        FS="\n"
        RS=""
}
{
        print $1","$2","$3
}
[root@Gin scripts]# awk -f awk.txt recode.txt
Jimmy the Weasel,100 Pleasant Drive,San Francisco,CA 123456
Big Tony,200 Incognito Ave.,Suburbia,WA 64890

NF 字段数量

$ cat hello.txt
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin:888
$ awk -F ":" 'NF==8{print $0}' hello.txt
bin:x:1:1:bin:/bin:/sbin/nologin:888

NR 行数

$cat /etc/passwd
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
$ awk '{print NR,$0}' /etc/passwd
1 root:x:0:0:root:/root:/bin/bash
2 bin:x:1:1:bin:/bin:/sbin/nologin
3 daemon:x:2:2:daemon:/sbin:/sbin/nologin

OFS 输出字段分隔符

$ cat hello.txt
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin:888
$awk 'BEGIN{FS=":"}{print $1","$2","$3}' hello.txt
root,x,0
bin,x,1
$ awk 'BEGIN{FS=":";OFS="#"}{print $1,$2,$3}' hello.txt
root#x#0
bin#x#1

ORS 输出记录分隔符

$ cat recode.txt
Jimmy the Weasel
100 Pleasant Drive
San Francisco,CA 123456
 
Big Tony
200 Incognito Ave.
Suburbia,WA 64890

$ cat awk.txt
#!/bin/awk
BEGIN {
        FS="\n"
        RS=""
        ORS="\n\n"
}
{
        print $1","$2","$3
}

$ awk -f awk.txt recode.txt
Jimmy the Weasel,100 Pleasant Drive,San Francisco,CA 123456
 
Big Tony,200 Incognito Ave.,Suburbia,WA 64890

awk 运算符

运算符	描述
`= += -= = 、= %= ……= *=`	赋值语句
`\|\|`	逻辑或
`&&`	逻辑与
`~ !~`	匹配正则表达式和不匹配正则表达式
`< <= > >= != ==`	关系运算符
`+ -`	加减
`* 、 &`	乘除求余
`+ - ！`	一元加、减，逻辑非
`^ ***`	求幂
`++ --`	增加或者减少
`$`	字段引用
空格	字符串连接符
`?:`	三目运算符
`in`	数组中是否存在某值

赋值运算
```
  $ awk 'BEGIN{a=5;a+=5;print a}'
  10
```

逻辑运算符

  $ awk 'BEGIN{a=1;b=2;print (a>2&&b>1,a=1||b>1)}'
  0 1   判断表达式 a>2&&b>1为真还是为假，后面的表达式同理

关系运算符

如： > < 可以作为字符串比较，也可以用作数值比较，关键看操作数如果是字符串就会转换为字符串比较。两个都为数字才转为数值比较。字符串比较：按照ascii码顺序比较
```
  $ awk 'BEGIN{a="11";if(a>=9){print "ok"}}' #无输出
  $ awk 'BEGIN{a=11;if(a>=9){print "ok"}}' 
  ok
  $ awk 'BEGIN{a;if(a>=b){print "ok"}}'
  ok
```
awk 算数运算符

说明，所有用作算术运算符进行操作，操作数自动转为数值，所有非数值都变为0。
```
  $ awk 'BEGIN{a="b";print a++,++a}'
  0 2
  $ awk 'BEGIN{a="20b4";print a++,++a}'
  20 22
```
这里的a++ , ++a与javascript语言一样：a++是先赋值加++；++a是先++再赋值

三目运算符 ?:

  $ awk 'BEGIN{a="b";print a=="b"?"ok":"err"}'
  ok
  $ awk 'BEGIN{a="b";print a=="c"?"ok":"err"}'
  err

awk 正则

规则表达式

awk '/REG/{action} ' file,/REG/为正则表达式，可以将$0 中，满足条件的记录送入到：action 进行处理

[root@Gin scripts]# awk '/root/{print $0}' passwd ##匹配所有包含root的行
root:x:0:0:root:/root:/bin/bash
operator:x:11:0:operator:/root:/sbin/nologin
 
[root@Gin scripts]# awk -F: '$5~/root/{print $0}' passwd  ## 以分号作为分隔符，匹配第5个字段是root的行
root:x:0:0:root:/root:/bin/bash
 
[root@Gin scripts]# ifconfig eth0|awk 'BEGIN{FS="[[:space:]:]+"} NR==2{print $4}'
192.168.17.129

布尔表达式 awk ‘布尔表达式{action}’ file 仅当对前面的布尔表达式求值为真时， awk 才执行代码块。

[root@Gin scripts]# awk -F: '$1=="root"{print $0}' passwd
root:x:0:0:root:/root:/bin/bash
[root@Gin scripts]# awk -F: '($1=="root")&&($5=="root") {print $0}' passwd
root:x:0:0:root:/root:/bin/bash

##awk 的 if、循环和数组

条件语句

awk 提供了非常好的类似于 C 语言的 if 语句

{
        if ($1=="foo"){
                if($2=="foo"){
                        print "uno"
                }else{
                        print "one"
                }
        }elseif($1=="bar"){
                print "two"
        }else{
                print "three"
        }
}

使用 if 语句还可以将代码：

! /matchme/ { print $1 $3 $4 }

转换成：

{
　　if ( $0 !~ /matchme/ ) {
　　　　print $1 $3 $4
　　}
}

循环结构

我们已经看到了 awk 的 while 循环结构，它等同于相应的 C 语言 while 循环。 awk 还有”do…while”循环，它在代码块结尾处对条件求值，而不像标准 while 循环那样在开始处求值。

它类似于其它语言中的”repeat…until”循环。以下是一个示例： do…while 示例

{
    count=1do {
        print "I get printed at least once no matter what"
    } while ( count !=1 )
}

与一般的 while 循环不同，由于在代码块之后对条件求值， “do…while”循环永远都至少执行一次。换句话说，当第一次遇到普通 while 循环时，如果条件为假，将永远不执行该循环。

for 循环

awk 允许创建 for 循环，它就象 while 循环，也等同于 C 语言的 for 循环：

for ( initial assignment; comparison; increment ) {
    code block
}

以下是一个简短示例：

for ( x=1;x<=4;x++ ) {
    print "iteration", x
}

此段代码将打印：

iteration1
iteration2
iteration3
iteration4

break 和 continue

此外，如同 C 语言一样， awk 提供了 break 和 continue 语句。使用这些语句可以更好地控制 awk 的循环结构。以下是迫切需要 break 语句的代码片断：

while 死循环
while (1) {
print "forever and ever..."
}
while 死循环 1 永远代表是真，这个 while 循环将永远运行下去。

以下是一个只执行十次的循环：

#break 语句示例
x=1
while(1) {
　　print "iteration", x
　　if ( x==10 ) {
　　　　break
　　}
　　x++
}

这里， break 语句用于“逃出”最深层的循环。 “break”使循环立即终止，并继续执行循环代码块后面的语句。 continue 语句补充了 break，其作用如下：

x=1while (1) {
        if ( x==4 ) {
        x++
        continue
    }
    print "iteration", x
    if ( x>20 ) {
        break
    }
    x++
}

这段代码打印”iteration1”到”iteration21”， “iteration4”除外。如果迭代等于 4，则增加 x并调用 continue 语句，该语句立即使 awk 开始执行下一个循环迭代，而不执行代码块的其余部分。如同 break 一样，

continue 语句适合各种 awk 迭代循环。在 for 循环主体中使用时， continue 将使循环控制变量自动增加。以下是一个等价循环：

for ( x=1;x<=21;x++ ) {
    if ( x==4 ) {
        continue
    }
    print "iteration", x
}

在while 循环中时，在调用 continue 之前没有必要增加 x，因为 for 循环会自动增加 x。

数组

AWK 中的数组都是关联数组,数字索引也会转变为字符串索引

{
    cities[1]=”beijing”
    cities[2]=”shanghai”
    cities[“three”]=”guangzhou”
    for( c in cities) {
        print cities[c]
    }
    print cities[1]
    print cities[“1”]
    print cities[“three”]
}

for…in 输出，因为数组是关联数组，默认是无序的。所以通过 for…in 得到是无序的数组。如果需要得到有序数组，需要通过下标获得。

数组的典型应用

用 awk 中查看服务器连接状态并汇总

netstat -an|awk '/^tcp/{++s[$NF]}END{for(a in s)print a,s[a]}'
ESTABLISHED 1
LISTEN 20

统计 web 日志访问流量，要求输出访问次数，请求页面或图片，每个请求的总大小，总访问流量的大小汇总

awk '{a[$7]+=$10;++b[$7];total+=$10}END{for(x in a)print b[x],x,a[x]|"sort -rn -k1";print
"total size is :"total}' /app/log/access_log
total size is :172230
21 /icons/poweredby.png 83076
14 / 70546
8 /icons/apache_pb.gif 18608
a[$7]+=$10 表示以第 7 列为下标的数组（ $10 列为$7 列的大小），把他们大小累加得到
$7 每次访问的大小，后面的 for 循环有个取巧的地方， a 和 b 数组的下标相同，所以一
条 for 语句足矣

常用字符串函数

函数	说明
`gsub(Ere,Repl,[in])`	除了正则表达式所有具体值呗替代这点，它和sub函数完全一样的执行
`sub (Ere,Repl,[in])`	用Repl参数指定的字符串替换in参数指定的字符串中的由Ere参数指定的扩展正则表达式的第一个具体值。sub 函数返回替换的数量。出现在Repl参数指定的字符串中的&（和符号）由in参数指定的与Ere参数的指定的扩展正则表达式匹配的字符串替换。如果未指定in参数，缺省值是整个记录（$0 记录变量）
`index(String1,String2)`	在由String1参数指定的字符串（其中有出现String2指定的参数）中，返回位置，从1开始编号。如果String2参数不在String1 参数中出现，返回0（零）
`length[(String)]`	返回String参数指定的字符串的长度（字符形式）。如果未给出String参数，则返回整个记录的长度（$0 记录变量)
`blength[(String)]`	返回String参数指定的字符串的长度（以字节为单位）。如果未给出String参数，则返回整个记录的长度（$0 记录变量)
`substr(String,M,[N])`	返回具有N参数指定的字符数量子串。子串从String参数指定的字符串取得，其字符以M参数指定的位置开始。M参数指定为将String参数中的第一个字符作为编号1.如果未指定N参数，则子串的长度将是M参数指定的位置到String参数的末尾的长度
`match(String,Ere)`	在String参数指定的字符串（Ere参数指定的扩展正则表达式出现在其中）中返回位置（字符形势），从1开始编号，或如果Ere参数不出现，则返回0.RSTART特殊变量设置为返回值。RLENGTH特殊变量设置为匹配的字符串的长度，或如果未找到任何匹配，则设置为 -1
`split(String,A[Ere]`	将String参数指定的参数分割为数组元素A[1],A[2]..A[n],并返回n变量的值。此分隔可以通过Ere参数指定的扩展正则表达式进行，或用当前字段分隔符（FS特殊变量）来进行（如果没有给出Ere参数）。除非上下文指定特定的元素还应具有一个数字值，否则A数组中的元素用字符串值来创建
`tolower(String)`	返回String参数指定的字符串，字符串中每个大写字符将更改为小写。大写和小写的映射油当前语言环境的LC_CTYPE范畴定义
`toupper(String)`	返回String参数指定的字符串，字符串中每个小写字符将更改为大写。大写和小写的映射油当前语言环境的LC_CTYPE范畴定义
`sprintf(Format,Expr,Expr,...)`	根据Format参数指定的printf子例程式字符串来格式化Expr参数指定的表达式并返回最后胜出的字符串。

字符串函数的应用

替换

awk 'BEGIN{info="this is a test2010test!";gsub(/[0-9]+/,"!",info);print info}' this is a test!test!
在 info 中查找满足正则表达式， /[0-9]+/ 用”!”替换，并且替换后的值，赋值给 info 未
给 info 值，默认是$0

查找

awk 'BEGIN{info="this is a test2010test!";print index(info,"test")?"ok":"no found";}'
ok #未找到，返回 0

匹配查找

awk 'BEGIN{info="this is a test2010test!";print match(info,/[0-9]+/)?"ok":"no found";}'
ok #如果查找到数字则匹配成功返回 ok，否则失败，返回未找到

截取

awk 'BEGIN{info="this is a test2010test!";print substr(info,4,10);}'
s is a tes #从第 4 个 字符开始，截取 10 个长度字符串

分隔

awk 'BEGIN{info="this is a test";split(info,tA," ");print length(tA);for(k in tA){print k,tA[k];}}' 4
4 test 1 this 2 is 3 a
#分割 info,动态创建数组 tA,awk for …in 循环，是一个无序的循环。 并不是从数组下标
1…n 开始

Larry